You canopen both databases in the Notes client.  Then select the desired items from the database and use the "Copy" command.  Then open the second databse (Target) and paste the items into the ded location on the second database.

This cannot be done - you cannot move folders/databases from one database to another via the GUI.

As mentioned, you can copy documents from database to another.

As a work-a-round it is possible to create a lotus script agent to do the desired move (from one DB to another):

Sub Initialize
    Dim s As New NotesSession
    Dim w As New NotesUIWorkspace
    Dim dbSource As NotesDatabase, dbDest As NotesDatabase
    Dim source As NotesView, dest As NotesView
    Dim vc As NotesViewEntryCollection
    Dim docDest As NotesDocument
    Dim ve As NotesViewEntry
    Dim folders() As String
    Dim i As Integer
    Dim ret, rez
    
    Set dbSource = s.CurrentDatabase
    
    Forall v In dbSource.Views
        If v.IsFolder Then
            i = i + 1
            Redim Preserve folders( i - 1 ) As String
            folders( i - 1 ) = v.Name
        End If
    End Forall
    
    ret = w.Prompt( PROMPT_OKCANCELLISTMULT, "Folder selection", 
"Select one or more folders to move.", folders(0), folders )
    If Isempty( ret ) Then 
        Messagebox "User canceled", , "Folder not selected" 
        Exit Sub
    Else
        Forall f In ret    
            Set source = dbSource.GetView( f )
            Set vc = source.AllEntries
            
            rez = w.Prompt( 13, "Database selection", 
"Choose the database to move the folder to" )
            If Isempty( rez ) Then Messagebox "User canceled", , 
"Database not selected" : Exit Sub
            
            Set dbDest = s.GetDatabase( rez(0), rez(1), False )
            Call dbDest.EnableFolder( f )
            
            Set ve = vc.GetFirstEntry
            Do Until ve Is Nothing
                Set docDest = ve.Document.CopyToDatabase( dbDest )
                Call docDest.PutInFolder( f )
                Set ve = vc.GetNextEntry( ve )
            Loop
            
            Call vc.RemoveAllFromFolder( f )
            Call source.Remove
        End Forall
    End If
End Sub

Regards,

Paul